overleaf/services/web/test/UnitTests/coffee/ConnectedUsers/ConnectedUsersManagerTests.coffee

should = require('chai').should()
SandboxedModule = require('sandboxed-module')
assert = require('assert')
path = require('path')
sinon = require('sinon')
modulePath = path.join __dirname, "../../../../app/js/Features/ConnectedUsers/ConnectedUsersManager"
expect = require("chai").expect
tk = require("timekeeper")


describe "ConnectedUsersManager", ->

	beforeEach ->

		@settings =
			redis:
				web:{}
		@rClient =
			auth:->
			setex:sinon.stub()
			sadd:sinon.stub()
			get: sinon.stub()
			srem:sinon.stub()
			del:sinon.stub()
			smembers:sinon.stub()
			expire:sinon.stub()
			hset:sinon.stub()
			hgetall:sinon.stub()
			exec:sinon.stub()
			multi: => return @rClient
		tk.freeze(new Date())

		@ConnectedUsersManager = SandboxedModule.require modulePath, requires:
			"settings-sharelatex":@settings
			"logger-sharelatex": log:->
			"redis": createClient:=> 
				return @rClient
		@user_id = "32132132"
		@project_id = "dskjh2u21321"

	afterEach -> 
		tk.reset()

	describe "markUserAsConnected", ->
		beforeEach ->
			@rClient.exec.callsArgWith(0)

		it "should set a key with the date and give it a ttl", (done)->
			@ConnectedUsersManager.markUserAsConnected @project_id, @user_id, (err)=>
				@rClient.hset.calledWith("connected_user:#{@project_id}:#{@user_id}", "connected_at", new Date()).should.equal true
				done()

		it "should push the user_id on to the project list", (done)->
			@ConnectedUsersManager.markUserAsConnected @project_id, @user_id, (err)=>
				@rClient.sadd.calledWith("users_in_project:#{@project_id}", @user_id).should.equal true
				done()

		it "should add a ttl to the connected user set so it stays clean", (done)->
			@ConnectedUsersManager.markUserAsConnected @project_id, @user_id, (err)=>
				@rClient.expire.calledWith("users_in_project:#{@project_id}", 24 * 4 * 60 * 60).should.equal true
				done()

		it "should add a ttl to the connected user so it stays clean", (done)->
			@ConnectedUsersManager.markUserAsConnected @project_id, @user_id, (err)=>
				@rClient.expire.calledWith("connected_user:#{@project_id}:#{@user_id}", 60 * 60).should.equal true
				done()

	describe "markUserAsDisconnected", ->
		beforeEach ->
			@rClient.exec.callsArgWith(0)

		it "should remove the user from the set", (done)->
			@ConnectedUsersManager.markUserAsDisconnected @project_id, @user_id, (err)=>
				@rClient.srem.calledWith("users_in_project:#{@project_id}", @user_id).should.equal true
				done()

		it "should delete the connected_user string", (done)->
			@ConnectedUsersManager.markUserAsDisconnected @project_id, @user_id, (err)=>
				@rClient.del.calledWith("connected_user:#{@project_id}:#{@user_id}").should.equal true
				done()

		it "should add a ttl to the connected user set so it stays clean", (done)->
			@ConnectedUsersManager.markUserAsDisconnected @project_id, @user_id, (err)=>
				@rClient.expire.calledWith("users_in_project:#{@project_id}", 24 * 4 * 60 * 60).should.equal true
				done()

	describe "_getConnectedUser", ->

		it "should get the user returning connected if there is a value", (done)->
			@rClient.hgetall.callsArgWith(1, null, {connected_at:new Date(), cursorData:{row:1}})
			@ConnectedUsersManager._getConnectedUser @project_id, @user_id, (err, result)=>
				result.connected.should.equal true
				result.user_id.should.equal @user_id
				done()

		it "should get the user returning connected if there is a value", (done)->
			@rClient.hgetall.callsArgWith(1)
			@ConnectedUsersManager._getConnectedUser @project_id, @user_id, (err, result)=>
				result.connected.should.equal false
				result.user_id.should.equal @user_id
				done()

	describe "getConnectedUsers", ->

		beforeEach ->
			@users = ["1234", "5678", "9123"]
			@rClient.smembers.callsArgWith(1, null, @users)
			@ConnectedUsersManager._getConnectedUser = sinon.stub()
			@ConnectedUsersManager._getConnectedUser.withArgs(@project_id, @users[0]).callsArgWith(2, null, {connected:true, user_id:@users[0]})
			@ConnectedUsersManager._getConnectedUser.withArgs(@project_id, @users[1]).callsArgWith(2, null, {connected:false, user_id:@users[1]})
			@ConnectedUsersManager._getConnectedUser.withArgs(@project_id, @users[2]).callsArgWith(2, null, {connected:true, user_id:@users[2]})


		it "should only return the users in the list which are still in redis", (done)->
			@ConnectedUsersManager.getConnectedUsers @project_id, (err, users)=>
				users.length.should.equal 2
				users[0].should.deep.equal {user_id:@users[0], connected:true}
				users[1].should.deep.equal {user_id:@users[2], connected:true}
				done()

	describe "setUserCursorPosition", ->

		beforeEach ->
			@cursorData = { row: 12, column: 9, doc_id: '53c3b8c85fee64000023dc6e' }
			@rClient.exec.callsArgWith(0)

		it "should add the cursor data to the users hash", (done)->
			@ConnectedUsersManager.setUserCursorPosition @project_id, @user_id, @cursorData, (err)=>
				@rClient.hset.calledWith("connected_user:#{@project_id}:#{@user_id}", "cursorData", JSON.stringify(@cursorData)).should.equal true
				done()


		it "should add the ttl on", (done)->
			@ConnectedUsersManager.setUserCursorPosition @project_id, @user_id, @cursorData, (err)=>
				@rClient.expire.calledWith("connected_user:#{@project_id}:#{@user_id}", 60 * 60).should.equal true
				done()